Merci à Benjamin Clerc pour ce texte qui présente des situations avancées en géométrie dynamique par exemple pour proposer différents aspects d’une construction dans une même figure.

NB : TracenPoche permet à partir de la version 2.25 de simplifier largement ces situation. En attendant la parution d’un nouvel article, aller faire un tour du côté de la variable varsi et de la fonction µ ainsi que du côté de l’objet pointAimante.

1. Curseurs de type potentiomètre

Intention

L’outil « var » de TracenPoche permet d’éditer un nombre entier ou réel ; l’utilisation d’un tel objet est interactive : on peut augmenter ou diminuer la valeur d’un nombre édité (à la souris). Un curseur de type potentiomètre permet d’obtenir une action continue sur un nombre (visuellement tout au moins) avec une plus grande souplesse d’utilisation que par incrémentation directe.

Principe

Le déplacement d’un point M sur un segment [AB] permet d’éditer un nombre x décrivant un intervalle I de IR choisi par l’utilisateur, suivant une échelle linéaire ou non : le quotient AM/AB décrit l’intervalle [0 ;1] lorsque M décrit [AB] ; une bijection (ou surjection) permettra d’obtenir un nombre décrivant I lorsque M décrit [AB].

Exemples :

f(x)=10(x-1/2) établit une bijection de [0,1] sur [-5 ;5] ;
f(x)=tan(Pi(x-1/2)) établit une bijection de [0 ;1] sur IR.

Exemple de mise en oeuvre

Construction de la représentation graphique dans un repère orthonormal (O ;I;J) d’une fonction affine f(x)=ax+b , a et b variant au moyen de curseurs ( b décrit l’intervalle [-5,5], et a décrit IR). construction des curseurs permettant la variation de a et b :

deux segments [AB] et [CD] ;	A = point(-7,6) ; B = point(-3,6) ; sAB =segment(A,B) ; C = point(-7,5) ; D = point(-3,5) ; sCD =segment(C,D) ;
deux points P sur [AB] et Q sur [CD] ;	P =pointsur(sAB,0.6) ; Q =pointsur(sCD,0.67) ;
Calcul des variables a et b	var a =tan(180*(AP/AB-1/2)) ; var b =12*(CQ/CD-1/2) ;
Écriture de la valeur des variables sur les curseurs, on choisit des valeurs arrondies au dixième ;	texte1 =texte(-6,6.7,"coefficient directeur : $a$") {violet,dec1} ; texte2 =texte(-6,5.7,"ordonnée à l’origine : $b$") {violet,dec1} ;
Les curseurs de type potentiomètre sont construits,	il ne reste plus qu’à les utiliser !
Construction de la représentation graphique de la fonction affine :	f(x)=ax+b
Affichage du repère	repereortho(323,263,40,1,1) ;
Points M(0 ;b) et N(1,a+b)	var c =a+b ; M = point(0,b) {i} ; N = point(1,c) {i} ;
On trace la droite (MN) et on écrit son équation.	dMN =droite(M,N) 0x009933,2,sansnom ; texte3 =texte(-3,5,"Représentation graphique de f(x) = $a$x + $b$") {orange,dec1} ;

Script « Curseurs de type potentiomètre »

@options ;
 repereortho(323,263,40,1,1) ;

@figure ;
 A = point(-7,6) {i} ;
 B = point(-3,6) {i} ;
 sAB =segment(A,B) ;
 C = point(-7,5) {i} ;
 D = point(-3,5) {i} ;
 sCD =segment(C,D) ;
 P =pointsur(sAB,0.76) {2,sansnom} ;
 Q =pointsur(sCD,0.67) {2,sansnom} ;
 var a =tan(180*(AP/AB-1/2)) ;
 texte1 =texte(-6,6.7,"coefficient directeur : $a$") {violet,dec1} ;
 var b =12*(CQ/CD-1/2) ;
 texte2 =texte(-6,5.7,"ordonnée à l’origine : $b$") {violet,dec1} ;
 var c =a+b ;
 M = point(0,b) {i} ;
 N = point(1,c) {i} ;
 dMN =droite(M,N) {0x009933,2,sansnom} ;
 texte3 =texte(-3,5,"Représentation graphique de f(x) = $a$x + $b$") {orange,dec1} ;

 

2. Curseurs logiques

Intention

Un curseur logique joue le rôle d’un interrupteur (à deux ou plusieurs positions) permettant de faire apparaître ou non une (ou plusieurs) constructions.

Principe

Cette construction se fait en deux étapes

 

-1. La construction « point conditionnel sur segment » crée un point X qui existe si et seulement si un point M appartient à un segment donné.

un segment [AB], son milieu I, le segment [IB] :	A = point(-5,5) {i ; B = point(0,5) {i} ; sAB =segment(A,B) ; I =milieu(A,B) {i} ; sIB =segment(I,B) ;
un point M sur le segment [AB] et la perpendiculaire d à [AB] en M :	M =pointsur(sAB,0.76) {vertfonce} ; d =perpendiculaire(M,sAB) {i} ;
le point d’intersection X de d et du segment [IB] :	X =intersection(d,sIB) {i} ;

On constate que X existe si et seulement si M appartient au segment [IB] ; X est alors confondu avec M.

 

-2. La construction « ping-pong » renvoie en un point donné C (que l’on cachera ensuite) le caractère conditionnel de X.

Réalisation :
on crée successivement le milieu de [XC] puis le symétrique Z de X par rapport à ce milieu.
On constate que Z existe (et est alors confondu avec C) si et seulement si M appartient à [IB]. Dès lors, toute construction bâtie sur Z n’apparaîtra que lorsque M appartient à [IB] :

C = point(0,0) {i} ;
J =milieu(X,C) {i} ;
sc_J =symetrie(J) {noir} ;
Z =image(sc_J,X) {rouge,3} ;

 

Script « Curseur logique »

@options ;

@figure ;
 A = point(-2,1) {i} ;
 B = point(2,1) {i} ;
 sAB =segment(A,B) ;
 I =milieu(A,B) {i} ;
 sIB =segment(I,B) ;
 M =pointsur(sAB,0.65) {vertfonce} ;
 d =perpendiculaire(M,sAB) {i} ;
 X =intersection(d,sIB) {i} ;
 C = point(0,0) {i} ;
 J =milieu(X,C) {i} ;
 sc_J =symetrie(J) {noir} ;
 Z =image(sc_J,X) {rouge,3} ;

      A gauche, le résultat <- -> A droite, ce qui est caché

---